|
|
Post by turbov21 on Oct 25, 2007 17:27:12 GMT -5
I keep mentally comparing Run BASIC to what I know about Dave Winer's Frontier Kernel: both have web servers, both are programmably extensible, both have a simple syntax. So, I thought, then shouldn't both be able to parse OPML? Well, now Run BASIC can: ' Sets the title bar
titlebar "OpmlTest"
[start]
cls
html "<h2>OPML Parsing Demo</h2>"
link #test, "Test OPML", [test]
print ""
link #dave, "Dave Winer's OPML", [dave]
wait
[test]
cls
xml$ = "<opml version=""1.0"">" + _
"<head>" + _
"<title>OPML Test</title>" + _
"</head>" + _
"<body>" + _
"<outline text=""This is a test."">" + _
"<outline text=""Has a child."">" + _
"<outline text=""Has a child too."" />" + _
"</outline>" + _
"</outline>" + _
"<outline text=""This is another test."" />" + _
"<outline text=""This is yet another test."" />" + _
"</body>" + _
"</opml>"
Call GetOpml xml$
goto [final]
[dave]
cls
xml$ = httpget$("http://www.scripting.com/index.opml")
Call GetOpml xml$
goto [final]
[final]
link #start, "Start Over", [start]
wait
'''''
' Parses the OPML based on a given string.
sub GetOpml xml$
xmlparser #opml, xml$
#head = #opml #element("head")
#title = #head #element("title")
html "<h2>" + #title value$() + "</h2>"
#body = #opml #element("body")
Call GetText #body
end sub
'''''
' Gets the text
sub GetText #outline
html "<ul>"
for i = 1 to #outline elementcount()
html "<li>"
#line = #outline #element(i)
print #line attribvalue$("text")
if #line elementcount() > 0 then
Call GetText #line
end if
html "</li>"
next i
html "</ul>"
end sub |
I'm not sure where this belongs, if at all, on the wiki, so I'm just going to paste it here for now. |
|
|
|
Post by Jerry Muelver on Oct 25, 2007 20:35:58 GMT -5
Sure, it belongs on the wiki! This could form the basis for a very dynamic RB Help system!
|
|
|
|
Post by Alyce on Oct 26, 2007 5:49:10 GMT -5
Heehee, Jerry would say that everything belongs on the wiki! And I'd have to agree. Why not put it here: runbasic.wikispaces.com/Sample+CodeIf one of the existing categories doesn't fit your code, just create a new category. Maybe a category "XML Parsing"? |
|
|
|
Post by turbov21 on Oct 26, 2007 11:51:31 GMT -5
If one of the existing categories doesn't fit your code, just create a new category. Maybe a category "XML Parsing"? That is an excellent idea! Thank you. |
|
